怎么编写bat文件

怎么编写bat文件，是什么语法，给几个范本~

【 echo 命令 】

打开回显或关闭请求回显功能，或显示消息。如果没有任何参数，echo 命令将显示当前回显设置。
语法
echo [{on|off}] [message]
Sample：@echo off / echo hello world
在实际应用中我们会把这条命令和重定向符号（也称为管道符号，一般用> >> ^）结合来实现输入一
些命令到特定的文件中。
【 rem 命令 】

注释命令，类似于在C语言中的/*--------*/，它并不会被执行，只是起一个注释的作用，便于别人阅读
和你自己日后修改。
:: 也具有rem的功能
但::和rem还是有区别的，当关闭回显时，rem和::后的内容都不会显示。但是当打开回显时，rem和rem
后的内容会显示出来，然而::后的内容仍然不会显示。
Rem Message
Sample：@Rem Here is the description.
【 pause 命令 】

暂停命令。运行 Pause 命令时，将显示下面的消息：
Press any key to continue. . .(或：请按任意键继续. . .)
Sample：
@echo off
:begin
copy G:*.* d：\back
echo 请插入另一张光盘...
pause
goto begin
在这个例子中，驱动器 G 中磁盘上的所有文件均复制到d:\back中。显示的注释提示您将另一张光盘
盘放入驱动器 G 时，pause 命令会使程序挂起，以便您更换光盘，然后按任意键继续处理。
【 call 命令 】

从一个批处理程序调用另一个批处理程序，并且不终止父批处理程序。call 命令接受用作调用目标的
标签。如果在脚本或批处理文件外使用 Call，它将不会在命令行起作用。
语法
call [[Drive:][Path] FileName ] [:label [arguments]]
参数
[Drive:}[Path] FileName
指定要调用的批处理程序的位置和名称。
【 start 命令 】

调用外部程序，所有的DOS命令和命令行程序都可以由start命令来调用。
如：start calc.exe 即可打开Windows的计算器。
常用参数：
MIN 开始时窗口最小化
SEPARATE 在分开的空间内开始 16 位 Windows 程序
HIGH 在 HIGH 优先级类别开始应用程序
REALTIME 在 REALTIME 优先级类别开始应用程序
WAIT 启动应用程序并等候它结束
parameters 这些为传送到命令/程序的参数
执行的应用程序是 32-位 GUI 应用程序时，CMD.EXE 不等应用程序终止就返回命令提示。如果在命令
脚本内执行，该新行为则不会发生。
【 goto 命令 】

跳转命令。程序指针跳转到指定的标签，从标签后的第一条命令开始继续执行批处理程序。
语法：goto label （label是参数，指定所要转向的批处理程序中的行。）
Sample：
if {%1}=={} goto noparms
if {%2}=={} goto noparms（如果这里的if、%1、%2你不明白的话，先跳过去，后面会有详细的解释
。）
@Rem check parameters if null show usage
:noparms
echo Usage: monitor.bat ServerIP PortNumber
goto end
标签的名字可以随便起，但是最好是有意义的字母啦，字母前加个：用来表示这个字母是标签，goto
命令就是根据这个：来寻找下一步跳到到那里。最好有一些说明这样你别人看起来才会理解你的意图啊。
【 set 命令 】

显示、设置或删除变量。
显示变量：set 或 set s 前者显示批处理当前已定义的所有变量及其值，后者显示所有以s开头的变量及值。
设置变量：set aa=abcd 此句命令便可向变量aa赋值abcd。如果变量aa已被定义，则aa的值被修改为abcd；若aa尚未定义，则此句命令即可定义新的变量aa，同时为变量aa赋予初始值abcd。
删除变量：set aa= 此句命令即可删除变量aa。若变量aa已被定义，则删除变量aa；若aa尚未定义，则此句命令为实质意义。
需要说明的是，批处理中的变量是不区分类型的，不需要像C语言中的变量那样还要区分int、float、char等。比如执行set aa=345后，变量aa的值既可以被视为数字345，也可以被视为字符串345。
set命令具有扩展功能，如用作交互输入、字符串处理、数值计算等，属于高级命令范畴。
[编辑本段]批处理符号简介

【 回显屏蔽 @ 】

表示不显示@后面的命令，在入侵过程中（例如使用批处理来格式化敌人的硬盘）自然不能让对方看到你使用的命令啦。
@用法举例：通过运行批处理文件对比pause和@pause命令即可明了@的效果。
【 重定向1 >与>> 】

将输出信息重定向到指定的设备或文件。系统默认输出到显示器。
如：echo aaaaa>a.txt 即可将本在显示器上显示的信息aaaaa输出到文件a.txt中，屏幕上没有任何显示。如果文件a.txt本来已经存在，该命令将首先擦除a.txt中的所有信息，然后写入信息aaaaa；若a.txt本来就不存在，该命令即可新建一个a.txt文件，并写入信息aaaaa。
echo aaaaa>>a.txt 类似于echo aaaaa>a.txt。区别在于：如果a.txt本已存在，>a.txt会擦除a.txt中的原有内容，而>>a.txt并不擦除原有内容，仅在a.txt文件的末尾添加信息aaaaa。a.txt不存在时，二者没有差别。
【 重定向2 < 】

将输入信息来源重定向为指定的设备或文件。系统默认从显示器读取输入信息。
重定向使用举例：
=========================================
@echo off
echo abcdefg——这是文件a.txt中的信息>a.txt
echo 请任意输入字符，以回车结束：
set /p ifo=
cls
echo 【 从屏幕获得的输入信息 】
echo %ifo%
set /p ifo=<a.txt
echo 【 从文件a.txt获得的输入信息 】
echo %ifo%
pause>nul
=========================================
读者观察命令与输出即可体会到重定向的功能和效果。
【 管道符号 | 】

将管道符号前面命令的输出结果重定向输出到管道符号后面的命令中去，作为后面命令的输入。使用格式为：command_1|command_2
管道符号使用举例：
=========================================
@echo off
echo aaaa>a.txt
del /p a.txt
pause
=========================================
@echo off
echo aaaa>a.txt
echo y|del /p a.txt
pause
=========================================
对比以上两个批处理执行结果，读者即可明白管道符的用法和效果。
需要说明的是，上面del命令添加开关/p只是为了让读者明白管道符号的使用方法，实际删除文件时不加/p开关即可实现无提示直接删除。
【 转义符 ^ 】

将特殊符号转化为一般符号，即剥离特殊符号的特殊地位。特殊符号指：| & > <
比如，如果我们想输出符号“>”，直接用命令 echo > 是不行的，必须修改为 echo ^> 。其余几个特殊符号类似需要有同样的处理。
转义字符使用举例：
=========================================
@echo off
echo aaaa>a.txt
echo 第一句echo执行完毕
echo aaaa^>a.txt
echo 第二句echo执行完毕
pause
=========================================
比较上面的两句echo，第一句echo将信息aaaa输出到了文件a.txt，而第二句echo则在直接屏幕上显示出aaaa>a.txt
【 逻辑命令符 】

逻辑命令符包括：&、&&、||
&-它的作用是用来连接n个DOS命令，并把这些命令按顺序执行，而不管是否有命令执行失败；
&&-当&&前面的命令成功执行时，执行&&后面的命令，否则不执行；
||-当||前面的命令失败时，执行||后面的命令，否则不执行。
=========================================
@echo off
echo ^|^|
reg add HKCU /v try /f||echo **成功**
reg add HKCU1 /v try /f||echo **失败**
echo ^&^&
reg delete HKCU /v try /f&&echo **成功**
reg delete HKCU /v try /f&&echo **失败**
echo ^&
reg delete HKCU /v try /f&echo **成功**
reg delete HKCU /v try /f&echo **失败**
pause
=========================================
执行reg add或reg delete后，系统会给出执行结果；我们通过echo命令也给出了“执行结果”。对比系统和我们自己给出的结果，既可以验证逻辑命令的判断机理。
[编辑本段]常用DOS命令释义

【 文件夹管理 】

cd 显示当前目录名或改变当前目录。
md 创建目录。
rd 删除一个目录。
dir 显示目录中的文件和子目录列表。
tree 以图形显示驱动器或路径的文件夹结构。
path 为可执行文件显示或设置一个搜索路径。
xcopy 复制文件和目录树。
【 文件管理 】

type 显示文本文件的内容。
copy 将一份或多份文件复制到另一个位置。
del 删除一个或数个文件。
move 移动文件并重命名文件和目录。(Windows XP Home Edition中没有)
ren 重命名文件。
replace 替换文件。
attrib 显示或更改文件属性。
find 搜索字符串。
fc 比较两个文件或两个文件集并显示它们之间的不同
【 网络命令 】

ping 进行网络连接测试、名称解析
ftp 文件传输
net 网络命令集及用户管理
telnet 远程登陆
ipconfig显示、修改TCP/IP设置
msg 给用户发送消息
arp 显示、修改局域网的IP地址-物理地址映射列表
【 系统管理 】

at 安排在特定日期和时间运行命令和程序
shutdown立即或定时关机或重启
tskill 结束进程
taskkill结束进程(比tskill高级，但WinXPHome版中无该命令)
tasklist显示进程列表(Windows XP Home Edition中没有)
sc 系统服务设置与控制
reg 注册表控制台工具
powercfg控制系统上的电源设置
对于以上列出的所有命令，在cmd中输入命令+/?即可查看该命令的帮助信息。如find /?
[编辑本段]语句结构释义

类似于C语言，批处理也有它的语句结构。批处理的语句结构主要有选择结构(if语句)、循环结构(for语句)等。
【 if语句(选择结构) 】

if语句实现条件判断，包括字符串比较、存在判断、定义判断等。通过条件判断，if语句即可以实现选择功能。
1、字符串比较
if语句仅能够对两个字符(串)是否相同、先后顺序进行判断等。其命令格式为：
IF [not] string1 compare-op string2 command1 [else command2]
其中，比较操作符compare-op有以下几类：
== - 等于
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于
选择开关/i则不区分字符串大小写；选择not项，则对判断结果进行逻辑非。
字符串比较示例：
===============================================
@echo off
set str1=abcd1233
set str2=ABCD1234
if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)
if /i %str1% LSS %str2% (echo str1^=str2)
echo.
set /p choice=是否显示当前时间？(y/n)
if /i not %choice% EQU n echo 当前时间是：%date% %time%
pause>nul
===============================================
对于最后一个if判断，当我们输入n或N时的效果是一样的，都不会显示时间。如果我们取消开关/i，则输入N时，依旧会显示时间。
另外请注意一下几个细节：1-echo str1^=str2；2-echo.。
2、存在判断
存在判断的功能是判断文件或文件夹是否存在。其命令格式为：
IF [NOT] EXIST filename command1 [else command2]
===============================================
@echo off
if exist %0 echo 文件%0是存在的！
if not exist %~df0 (
echo 文件夹%~df0不存在！
) else echo 文件夹%~df0存在！
pause>nul
===============================================
这里注意几个地方：
1-存在判断既可以判断文件也可以判断文件夹；
2-%0即代表该批处理的全称(包括驱动器盘符、路径、文件名和扩展类型)；
3-%~df0是对%0的修正，只保留了其驱动器盘符和路径，详情请参考for /?，属高级批处理范畴；
4-注意if语句的多行书写，多行书写要求command1的左括号必须和if在同一行、else必须和command1的右括号同行、command2的左括号必须与else同行、command1和command2都可以有任意多行，即command可以是命令集。
3、定义判断
定义判断的功能是判断变量是否存在，即是否已被定义。其命令格式为：
IF [not] DEFINED variable command1 [else command2]
存在判断举例：
===============================================
@echo off
set var=111
if defined var (echo var=%var%) else echo var尚未定义！
set var=
if defined var (echo var=%var%) else echo var尚未定义！
pause>nul
===============================================
对比可知，"set var="可以取消变量，收回变量所占据的内存空间。
4、结果判断
masm %1.asm
if errorlevel 1 pause & edit %1.asm
link %1.obj
先对源代码进行汇编，如果失败则暂停显示错误信息，并在按任意键后自动进入编辑界面；否则用link程序连接生成的obj文件，这种用法是先判断前一个命令执行后的返回码（也叫错误码，DOS程序在运行完后都有返回码），如果和定义的错误码符合（这里定义的错误码为1），则执行相应的操作（这里相应的操作为pause & edit %1.asm部分）。
另外，和其他两种用法一样，这种用法也可以表示否定。用否定的形式仍表达上面三句的意思，代码变为：
masm %1.asm
if not errorlevel 1 link %1.obj
pause & edit %1.asm
【 for语句(循环结构) 】

for语句可以实现类似于C语言里面的循环结构，当然for语句的功能要更强大一点，通过不同的开关可以实现更多的功能。for语句有多个开关，不同开关将会实现不同的功能。
1、无开关
无开关的for语句能够对设定的范围内进行循环，是最基本的for循环语句。其命令格式为：
FOR %%variable IN (set) DO command
其中，%%variable是批处理程序里面的书写格式，在DOS中书写为%variable，即只有一个百分号(%)；set就是需要我们设定的循环范围，类似于C语言里面的循环变量；do后面的command就是循环所执行的命令，即循环体。
无开关for语句举例：
===============================================
@echo off
for %%i in (a,"b c",d) do echo %%i
pause>nul
===============================================
2、开关/L
含开关/L的for语句，可以根据set里面的设置进行循环，从而实现对循环次数的直接控制。其命令格式为：
FOR /L %%variable IN (start,step,end) DO command
其中，start为开始计数的初始值，step为每次递增的值，end为结束值。当end小于start时，step需要设置为负数。
含开关/L的for语句举例(创建5个文件夹)：
===============================================
@echo off
for /l %%i in (1,2,10) do md %%i
pause
===============================================
上例将新建5个文件夹，文件夹名称依次为1、3、5、7、9。可以发现，%%i的结束值并非end的值10，而是不大于end的一个数。
3、开关/F
含开关/F的for语句具有最强大的功能，它能够对字符串进行操作，也能够对命令的返回值进行操作，还可以访问硬盘上的ASCII码文件，比如txt文档等。其命令格式为：
FOR /F ["options"] %%variable IN (set) DO command
其中，set为("string"、'command'、file-set)中的一个；options是(eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq)中的一个或多个的组合。各选项的意义参见for /f。一般情况下，使用较多的是skip、tokens、delims三个选项。
含开关/F的for语句举例：
===============================================
@echo off
echo **No Options:
for /f %%a in ("1,2,10") do echo a=%%a
echo **Options tokens ^& delims:
for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c
pause
===============================================
@echo off
echo 本文件夹里面的文件有：
for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (
if not "%%a"=="" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b
)
pause
===============================================
@echo off
echo 本文件夹里面的文件有：
dir>c:\file.txt
for /f "skip=5 tokens=3* delims= " %%a in (c:\file.txt) do (
if not "%%a"=="" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b
)
del c:\file.txt
pause
===============================================
对于后面的两个例子，其中options里面的delims= 是可以删除的，因为只要添加了/F开关系统就将delims的值默认为空格。
符号字符串中的最后一个字符星号，
那么额外的变量将在最后一个符号解析之后
分配并接受行的保留文本。本例中也可以改为4，不过文件名中有空格的文件，只能显示空格以前部分
同时我们也看到了，for语句的do后面的command也是可以分行的，只需要保证command的左括号和do在同一行就可以了。
4、开关/D或/R
含开关/D或/R的for语句是与目录或文件有关的命令，一般情况下很少使用。含开关/R的命令有时候被用于通过遍历文件夹来查找某一个文件或文件夹，故而列举此例。
含开关/R的for语句举例(文件夹遍历)：
===============================================
@echo off
setlocal enabledelayedexpansion
FOR /R d: %%i IN (.) DO (
set dd=%%i
set "dd=!dd:~0,-1!"
echo !dd!
)
pause
exit
===============================================
上例即可以罗列出D盘下的所有文件夹，其速度要比命令"tree d:"慢多了，不过其返回结果的实用性则远远超过了tree命令。
一般情况下我们不推荐通过遍历文件夹来查找文件，特别是在查找某些程序(比如QQ.exe)的位置时。推荐通过reg命令查找注册表来查找QQ的路径，以保证查找效率。
上例中也出现了几个新面孔，如setlocal、感叹号等。其中，感叹号其实就是变量百分号(%)的强化版。之所以要用!而不用%，是因为在for循环中，当一个变量被多次赋值时，%dd%所获取的仅仅是dd第一次被赋予的值；要想刷新dd的值，就必须首先通过命令"setlocal enabledelayedexpansion"来开启延迟变量开关，然后用!dd!来获取dd的值。
for语句是批处理里面功能最强大、使用最普遍却又最难掌握的一套命令，这也是批处理菜鸟和批处理高手最明显的一个分水岭，一旦掌握了这套命令，那么你就离批处理达人不远了！
参考http://baike.baidu.com/view/80110.htm?fr=ala0_1_1#3_2

1、首先，在电脑桌面右键单击空白处，在新建一个文本文档。

2、然后，在文本文档中输入需要执行查看IP地址的命令。

3、接着，按enter回车键，再输入我们需要执行的命令和网关地址。

4、之后，输入暂停按钮的命令，再保存该文本文档后，并关闭它。

5、点选文本文档，再按键盘上的F2键，再把文本文档命名为***.bat的文件。

6、最后，在弹出的重命名的提示窗口中点击确定按钮即可。

在这里一编写一个开启WIN7虚拟无线路由的bat文件为例

首先新建一新建记事本，为TXT格式

输入所要执行的命令
“netsh wlan start hostednetwork ”
进行保存

对新建的文件进行“重命名”，如果未显示后缀名，可以先设置一下显示后缀名

记得把“txt”也删了，修改为“start.bat”,这样可以更改文件的格式
如图所示

6
现在，bat文件就已经做好了，双击打开即可运行

---

大田县18087554357： 如何编写简单的bat文件 - ？
巨卞牙痛： 打开记事本,输入: dir pause 然后点击文件,另存为,保存类型选择:所有文件,然后输入文件名:aa.bat,点击确定. 简单的BAT文件就创建好了,点击即可运行,显示当前目录里的文件.

大田县18087554357： bat文件怎么写出来? - ？
巨卞牙痛： bat文件就是批处理文件,实际上就是由多个单一的命令组成的.记事本等都可以写的. 比如说,新建一个XP的用户登录账户,要两个两个命令就可以了,用记事本把这两个命令并列在一起另存为.bat文件,它就成为最简单的bat文件了(只有两条命令).

大田县18087554357： 怎样编写BAT代码 - ？
巨卞牙痛： 是,保存为格式选“所有文件”,文件名打 XXX.bat 以下是常见的命令 del XXX.XXX 删除文件 md XXX 新建文件夹 rd XXX 删除空文件夹 copy XXX.XXX XXX.XXX 复制文件 pause 暂停 cd XXXX\XXX\XX 更改工作路径 XXX.exe 运行程序 start XXX 打开程序

大田县18087554357： 如何制作bat文件?？
巨卞牙痛： @echo off ipconfig /all pause 这是一个简单的.只要把它复制到记事本内.另存为“查看内网IP.bat＂就可以了.还有更多,要学会DOS来.就可以了.

大田县18087554357： bat文件怎么写??谁来教教我!？
巨卞牙痛： 方法很多,可以使用专用的编辑软件.在不使用第三方软件的情况下有以下两种方法: 1.打开系统自带的记事本(在开始菜单→附件中找),把代码输入到里面,然后单击文件菜单的保存,文件名的格式为 文件名.bat,文件类型选择“所有文件”,单击保存就行了 2.在目标文件夹单击右键,新建文本文档,命名为 文件名.bat,然后在文件上单击右键,选择“编辑”,输入代码保存就行了

大田县18087554357： 怎么写bat的运行程序 - ？
巨卞牙痛： 先把缓存文件的路径从注册表里找出来,也就是类似与＂%temp%＂的文件夹,然后找一些常用的临时文件后缀.这些做完后就是删除工作,rd 命令是用来删文件夹的,del用来删文件.md用来建立文件夹. 比如说: rem 不显示命令行 @echo off cls rem 删除临时文件夹 rd /s/q %temp% md %temp% rem 删除临时文件 for %%a in (tmp log gid chk old) do del /a /s /q /f ＂%systemroot%\*.%%a＂ 打开记事本,把这些保存为*.bat

大田县18087554357： 要安装好多软件,怎么编写.bat文件呢? - ？
巨卞牙痛： 很简单.1.你把你所有想装的软件都放到一个文件夹下.2.点开始-运行.3.在输入框里输入CMD4.在出来的显示框里用CD 和CD.. 找到你的那个文件夹.5.然后下面就是关键的了.比如你的那个文件夹在D盘下,名字叫123.你的当前目录是d:\123> 然后在...

大田县18087554357： 如何编写BAT文件？
巨卞牙痛： 用记事本. 只要你熟悉DOS命令,编写好以后 保存 直接将扩展名改成.bat或.cmd就成了一个批处理文件了

大田县18087554357： 编写一个简单的bat文件 - ？
巨卞牙痛： 程序如下:@echo off:start set /p a=请选择1-start,2-stop或3-exit:IF “%a%＂ = ＂1＂ netsh wlan start hostednetwork IF “%a%＂ = ＂2＂ netsh wlan stop hostednetwork IF ＂%a%＂ = ＂3＂ goto :end goto start:end

大田县18087554357： 编写一个简单bat文件.过程描述如下: - ？
巨卞牙痛： 按照你的思路,需要知道以下几点,1.netdriver的进程名2.netdriver软件的启动程序所在路径3.日志的所在路径和格式4.你要批处理隐藏运行还是现实运行 最后一项清空回收站没必要,因为用批处理删除文件是不放入回收战的.手机上了,满足我说的明天你代码.