求一个以单片机为核心，组成一个电子时钟系统的程序

求写个单片机代码。以单片机为核心设计一个电子钟。单片机频率设为12mhz 。~

你好！需要用时钟芯片吗？

调用定时器中断，发出一个频率1s的脉冲，用这个来计数。加上几个按键，按键接收到一个电平信号这个数也+1。满60清零，分钟那个数+1，分钟满60清零，小时加1。在循环中不停的和你设定的定时时间做对比，一旦相同就启动蜂鸣器提醒。

;----------------------------------------------------------
;文件名称：SZ03.ASM
;程序功能：带定时闹铃及倒计时时钟
;----------------------------------------------------------
;－－－－－－－－――― 时钟程序部分 －－－――――――――
;－－－－－ ――― 程序初始化 ――――――――――
; 定义存放计时单元地址
;....................
ALB EQU 20H.0 ;闹铃设置标志
;....................
BUF EQU 30H ;30～33H 连续4字节存放显示器数据
HOUR EQU 34H ;存放小时变量
MIN EQU 35H ;存放分钟变量
SEC EQU 36H ;存放秒钟变量
DEDA EQU 37H ;存放5 ms 计数值
;....................
HH EQU 38H ;闹铃设置小时变量
MM EQU 39H ;闹铃设置分钟变量
;....................
;--------------------------------
SEC0 EQU 3AH ;存放旧的秒数
MM_D EQU 3BH ;倒数时间分钟数
SS_D EQU 3CH ;倒数时间秒钟数
;--------------------------------
;按键输入引脚定义
K1 EQU P2.4 ;按键1引脚定义
K2 EQU P2.5 ;按键2引脚定义
K3 EQU P2.6 ;按键3引脚定义
K4 EQU P2.7 ;按键4引脚定义

;压电喇叭和指示灯引脚定义
SPK EQU P3.4 ;压电喇叭控制信号
WLED EQU P1.0 ;工作指示灯引脚定义

;程序开始执行地址
ORG 0H ;程序代码由地址0开始执行
JMP MAIN
ORG 0BH ;定时器 0 中断地址设置
JMP TO_SRV

;－－－－－－－－－ 主 程 序 －－－－－－－－――

MAIN: ;开始
;...................
CLR ALB ;清除闹铃标志
;...................
ACALL BZ ;压电喇叭连续两次鸣响一声
ACALL BZ
ACALL LED_BL ;LED 闪动，表示程序开始执行
ACALL INIT ;初始变化量
ACALL INIT_TIMER ;设置定时器

;加载显示器初值数据
MOV A, #0C0H
MOV P0, A

;无穷循环
LOOP: ;无穷循环
ACALL CONV ;转换 时时 分分 数据
;....................
ACALL TIME_PRO ;检查闹铃时间
;....................
ACALL DISP ;扫描显示

JB K1, M1 ;未按下K1键则继续扫描
ACALL LED_BL ;LED闪动
ACALL SET_TIME ;设置目前时间
JMP LOOP ;继续循环执行

;设置闹铃时间
M1:JB K2,M2 ;未按下K2键则继续扫描
;.....................
ACALL LED_BL
ACALL SET_ATIME ;设置闹铃时间
;.....................
JMP LOOP ;继续循环执行

;设置倒计时间
M2:JB K3, M3 ;未按下K3键则继续扫描
;---------------------------------
ACALL LED_BL
ACALL DOWN_ATIME ;设置倒计时间
;--------------------------------
JMP LOOP ;继续循环执行

M3:JB K4,M4 ;未按下K4键则继续扫描
;...................
CPL ALB
JNB ALB,M31

;闹铃启动连续3次发出响声
ACALL BZ
ACALL BZ
ACALL BZ
;...................
JMP LOOP ;继续循环执行
;....................
M31:
ACALL BZ ;闹铃停止，发出一声响
JMP LOOP ;继续循环执行
;...................
M4:
JMP LOOP ;继续循环执行

;－－－－－ 实现走时功能的子程序 －－－－－－――

;使用定时器0模式0计时
INIT_TIMER: ;初始化定时器，使用定时器0模式1计时
MOV TMOD,#00000000B ;设置定时器0工作模式为0
MOV IE, #10000010B ;启用定时器0中断产生
MOV TL0, #(8192-4900)MOD 32 ;加载低字节
MOV TH0, #(8192-4900)/32 ;加载高字节
SETB TR0 ;启动定时器0开始计时
RET
;－－－－－－－－－－－―――
;中断服务程序
TO_SRV: ;定时器0计时中断程序每隔5ms中断一次
PUSH ACC ;将累加器放入堆栈
MOV TL0, #(8192-4900)MOD 32 ;加载低字节
MOV TH0, #(8192-4900)/32 ;加载高字节
INC DEDA ;5ms计数值加1
;秒输出
MOV A, DEDA
CJNE A,#200,TT1 ;是否1s到了
MOV DEDA, #0 ;计数值清除为0
CPL WLED ;LED灯亮灭变换
INC SEC ;秒计数加1
MOV A, SEC
CJNE A, #60, TT1;是否1min到了
;分输出
INC MIN ;分计数加1
MOV SEC, #0 ;秒计数清除为0
MOV A, MIN
CJNE A, #60, TT1 ;是否1h到了
;时输出
INC HOUR ;小时计数加1
MOV MIN, #0 ;分计数清除为0
MOV A, HOUR
CJNE A,#24, TT1 ;是否24h到了
MOV SEC, #0 ;秒钟变量清除为0
MOV MIN, #0 ;分钟变量清除为0
MOV HOUR, #0 ;小时变量清除为0
TT1:
POP ACC ;将累加器由堆栈取出
RETI

;－－－－―― 实现显示功能的子程序 －－－――――

;转换 时时：分分 数据
CONV:
;转换小时数据
MOV A, HOUR
MOV B, #10
DIV AB
MOV DPTR,#TABLE ;查表转换
MOVC A, @A+DPTR
MOV BUF, A
MOV A, B
MOVC A, @A+DPTR
MOV BUF+1, A
;转换分钟数据
MOV A, MIN
MOV B, #10
DIV AB
MOV DPTR,#TABLE ;查表转换
MOVC A, @A+DPTR
MOV BUF+2, A
MOV A, B
MOVC A, @A+DPTR
MOV BUF+3, A
RET

;字型数据编码表
TABLE:
DB 0C0H,0F9H,0A4H,0B0H
DB 99H,92H,82H,0F8H
DB 80H,90H,88H,83H
DB 0C6H,0A1H,86H,8EH

;－－－－－－－－－――――
;扫描显示
DISP:
MOV R0, #BUF ;指向显示器显示缓冲区起始地址
MOV R2, #4 ;循环执行4次
MOV ACC, #11110111b;加载扫描信号初值11110111B
S1:
PUSH ACC
MOV A, @R0 ;取出显示器数据
MOV P0, A ;由P0送出一位显示器数据
POP ACC
MOV P2, ACC ;由P2送出扫描输出信号
MOV R5, #2 ;延迟一会儿
ACALL DELAY
;改变扫描码 EX:XXXX1011
RR A ;累加器向右移动一位
INC R0 ;显示器显示缓冲区地址加1
DJNZ R2, S1 ;循环判断是否继续执行
RET

;－－－―― 实现调整时间子程序 ――――――

;设置目前时间
SET_TIME:
CLR TR0 ;定时器动作暂停
MOV SEC, #0 ;秒钟变量清除为0
L0:
ACALL DISP ;扫描显示

JB K2, L1 ;未按下K2键则继续扫描
JNB K2, $ ;有按下则等待放开来
;K2小时调整
INC HOUR ;小时计数加1
MOV A, HOUR
CJNE A,#24, L11 ;是否24H到了
MOV HOUR, #0 ;小时变量清除为0
L11:
ACALL CONV ;转换显示数据
ACALL DISP ;扫描显示
JMP L0 ;继续程序执行

L1:JB K3, L2 ;未按下K3键则继续扫描
JNB K3,$ ;有按下则等待放开来
;K3分钟调整.
INC MIN ;分钟计数加1
MOV A, MIN
CJNE A,#60, L21 ;是否60 min到了
MOV MIN, #0 ;分钟变量清除为0
L21:
ACALL CONV ;转换显示数据
ACALL DISP ;扫描显示
JMP L0 ;继续程序执行

L2: JB K4,L0 ;未按下K4键则继续扫描
JNB K4, $ ;有按下则等待放开来
ACALL BZ ;压电喇叭鸣响一声
;K4设置完成
ACALL LED_BL ;LED闪动
SETB TR0 ;启动定时器
RET

;－－－－―喇叭和指示灯等其它子程序 －－－－――

;计时单元清零
INIT:
MOV DEDA, #0 ;5ms计数值清除为0
MOV SEC, #0 ;秒钟变量清除为0
MOV MIN, #0 ;分钟变量清除为0
MOV HOUR, #0 ;小时变量清除为0
RET
;―――――――――――――
;压电喇叭
BZ: ;压电喇叭鸣响一声
MOV R6, #250
B1: ACALL DEX
CPL SPK
DJNZ R6,B1
MOV R5, #50 ;#10
ACALL DELAY
RET

;－－－－－－－－－－―――
;工作指示
LED_BL: ;工作指示灯闪烁
MOV R4,#6
LE1:CPL WLED ;位反向
MOV R5,#25 ;#5
ACALL DELAY
DJNZ R4, LE1 ;延迟50ms
RET
;－－－－－－－－－－―――
;延时子程序
DELAY: ;;总延迟时间 R5* 2ms
MOV R6,#10 ;#50
D1:MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;－－－－－－－－－－―――
; 压电喇叭短暂延时子程序
DEX: MOV R7,#180 ;短暂延时
DE1: NOP
DJNZ R7, DE1
RET

;－－－－－－－―― 增加定时闹铃程序部分 －－－－－－－――
;―――――――― 设置闹铃时间 ―――――――――
;设置闹铃时间
SET_ATIME:
ACALL CONVA ;加载闹铃时间数据
N0:
ACALL DISP
;－－－－－－－－－－－
JB K2, N1 ;未按下K2键则继续扫描
JNB K2, $ ;有按下则等待放开来
;K2调整小时
INC HH ;小时数加1
MOV A, HH
CJNE A, #24,N11 ;是否24h到了
MOV HH,#0 ;小时请为0
N11:
ACALL CONVA ;加载闹铃时间数据
ACALL DISP ;扫描显示
JMP N0 ;继续按键扫描
;－－－－－－－－－－－－
N1: JB K3, N2 ;未按下K3键则继续扫描
JNB K3, $ ;有按下则等待放开来
;K3调整分钟
INC MM ;调整分钟数
MOV A,MM ;分钟数加1
CJNE A, #60,N21 ;是否60min到了
MOV MM, #0 ;分钟数请为0
N21:
ACALL CONVA ;加载闹铃时间数据
ACALL DISP ;扫描显示
JMP N0 ;继续按键扫描
;－－－－－－－－－－－－
N2: JB K4, N0 ;未按下K4键则继续扫描
JNB K4, $ ;等K4键放开
;K4设置完成......
ACALL LED_BL ;LED闪动
ACALL CONV ;加载现在时间数据
RET

;―――――――― 加载闹铃时间数据 ―――――――

;转换 时时：分分 数据
CONVA:
;转换小时数据
MOV A, HH
MOV B, #10
DIV AB
;－－－－－－－－－－－
MOV DPTR,#TABLE ;查表转换
MOVC A, @A+DPTR
MOV BUF, A
;－－－－－－－－－－－
MOV A, B
MOVC A, @A+DPTR
MOV BUF+1, A
;转换分钟数据
MOV A, MM
MOV B, #10
DIV AB
;－－－－－－－－－－－
MOV DPTR,#TABLE ;查表转换
MOVC A, @A+DPTR
MOV BUF+2, A
;－－－－－－－－－－－
MOV A, B
MOVC A, @A+DPTR
MOV BUF+3, A
RET

;―――――――― 检查闹铃时间处理 ――――――――

;检查是否启动闹铃
TIME_PRO:
JB ALB, TI3
RET
;――――――――――――――

;检查闹铃时间是否到了
TI3:
MOV A, HOUR
MOV B,HH
CJNE A, B, BK ;检查闹铃小时时间
;－－－－－－－－－－－
MOV A, MIN
MOV B,MM
CJNE A, B, BK ;检查闹铃分钟时间
;－－－－－－－－－－－
ACALL TIME_OUT ;执行检查闹铃时间到了处理
BK:
RET

;－－－－－－－－ 执行闹铃时间处理 ――――――――

TIME_OUT: ;所设置的闹铃数据到了
X1: ACALL LED_BL ;LED闪动
ACALL BZ ;压电喇叭发出哗的一声
;按下K4键停止闹铃
JB K4, X1 ;等待是否按下K4键
JNB K4,$ ;若有按下键则等待按键放开来
ACALL LED_BL ;LED闪动
CLR ALB ;清除闹铃位
RET

;************************ 增加倒计时程序部分 *********************

;－－－－－－－－－－ 设置倒数时间 －－－－－－－－－－
;设置倒数时间
DOWN_ATIME:
CLR TR0 ;定时器动作暂停
MOV SS_D, #1 ;秒钟变量为1
S0:
ACALL DISP ;扫描显示
;－－－－－－－－－－－
;按K2分钟数增加
JB K2, S12 ;未按下K2继续扫描
JNB K2, $ ;有按下则等待放开来

INC MM_D ;分钟数加1
MOV A, MM_D
CJNE A, #60,S11 ;是否60min到了
MOV MM_D,#0 ;分钟变量请除为0
S11:
ACALL DOWN_CONV ;显示倒数的时间
ACALL DISP ;扫描显示
JMP S0 ;继续对按键扫描
;－－－－－－－－－－－－
;按K3分钟数减少
S12: JB K3, S2 ;未按下K3继续扫描
JNB K3, $ ;有按下则等待放开来

DEC MM_D ;分钟数减少1
MOV A,MM_D
CJNE A, #0,S21 ;是否为0？
MOV MM_D, #60 ;分钟数赋值为60
S21:
ACALL DOWN_CONV ;加载倒数时间数据
ACALL DISP ;扫描显示
JMP S0 ;循环执行
;－－－－－－－－－－－－
S2: JB K4, S0 ;未按下K4继续扫描
JNB K4, $ ;等K4键放开
;K4设置完成......
ACALL BZ ;响4声
ACALL BZ
ACALL BZ
ACALL BZ

ACALL LED_BL ;LED闪动
SETB TR0 ;启动定时器

S3:
ACALL DOWN_TIME ;检查倒计时
ACALL DOWN_CONV ;加载倒数时间数据
ACALL DISP ;扫描显示
JMP S3

RET

;---------------- 加载倒计时时间 -----------------------
;显示倒数的分钟数
DOWN_CONV:
MOV A, MM_D
MOV B,#10 ;设置被除数
DIV AB ;除法运算，结果A存商数，B存余数
MOV DPTR,#TABLE ;查表转换
MOVC A, @A+DPTR
MOV BUF+2, A ;商数存入BUF+2
MOV A, B ;余数暂存入A
MOVC A, @A+DPTR ;查表转换
MOV BUF+3, A ;余数存入BUF+3
RET

;－－－－－－－－－－ 检查倒计时 －－－－－－－－－－－－
;检查倒计时
DOWN_TIME: ;检查是否倒数终止
MOV A,SEC ;加载现在秒数
MOV B,SEC0 ;载入旧秒数
CJNE A,B,D01 ;是否过了1秒
RET
;-----------------------------------
D01:
MOV SEC0,SEC ;记录旧的秒数
DEC SS_D ;秒数减1
MOV A,SS_D
CJNE A,#0, D11 ;秒钟数是否为0
MOV A,MM_D
CJNE A,#0,D12 ;分钟数是否为0
;秒钟数＝0 且 分钟数＝0 则倒数终止
ACALL TIME_OUT ;倒数终了处理程序
JMP LOOP
RET
;－－－－－－－－－－－
D12:
MOV SS_D,#59 ;秒钟数＝59
DEC MM_D ;分钟数减1

D11:
ACALL DOWN_CONV ;显示倒计时时间
RET
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
END

这个不难，晚上传给你

;************* 数码管电子时钟 *******************;
;*MCU: AT892051 ;
;*MCU-crystal: 12M ;
;*Version: 01 ;
;*Last Updata: 2007-6-13 ;
;*Author: zhaojun ;
;*Description: ;
;定时器T0、T1溢出周期为50MS，T0为秒计数用 ;
;T1为调整时闪烁用 ;
;P3.7为调整按钮,P1口为字符输出口,采用共阳显示管 ;
;************************************************;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; AT89C2051时钟程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 中断入口程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ORG 0000H ;程序执行开始地址
LJMP START ;跳到标号START执行
ORG 0003H ;外中断0中断程序入口
RETI ;外中断0中断返回
ORG 000BH ;定时器T0中断程序入口
LJMP INTT0 ;跳至INTTO执行
ORG 0013H ;外中断1中断程序入口
RETI ;外中断1中断返回
ORG 001BH ;定时器T1中断程序入口
LJMP INTT1 ;跳至INTT1执行
ORG 0023H ;串行中断程序入口地址
RETI ;串行中断程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 主 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
START: MOV R0,#70H ;清70H-7AH共11个内存单元
MOV R7,#0BH ;
CLEARDISP: MOV @R0,#00H ;
INC R0 ;
DJNZ R7,CLEARDISP ;
MOV 20H,#00H ;清20H（标志用）
MOV 7AH,#0AH ;放入"熄灭符"数据
MOV TMOD,#11H ;设T0、T1为16位定时器
MOV TL0,#0B0H ;50MS定时初值（T0计时用）
MOV TH0,#3CH ;50MS定时初值
MOV TL1,#0B0H ;50MS定时初值（T1闪烁定时用）
MOV TH1,#3CH ;50MS定时初值
SETB EA ;总中断开放
SETB ET0 ;允许T0中断
SETB TR0 ;开启T0定时器
MOV R4,#14H ;1秒定时用初值（50MS×20）
START1: LCALL DISPLAY ;调用显示子程序
JNB P3.7,SETMM1 ;P3.7口为0时转时间调整程序
SJMP START1 ;P3.7口为1时跳回START1
SETMM1: LJMP SETMM ;转到时间调整程序SETMM
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 1秒计时程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中断服务程序
INTT0: PUSH ACC ;累加器入栈保护
PUSH PSW ;状态字入栈保护
CLR ET0 ;关T0中断允许
CLR TR0 ;关闭定时器T0
MOV A,#0B7H ;中断响应时间同步修正
ADD A,TL0 ;低8位初值修正
MOV TL0,A ;重装初值（低8位修正值）
MOV A,#3CH ;高8位初值修正
ADDC A,TH0 ;
MOV TH0,A ;重装初值（高8位修正值）
SETB TR0 ;开启定时器T0
DJNZ R4, OUTT0 ;20次中断未到中断退出
ADDSS: MOV R4,#14H ;20次中断到（1秒）重赋初值
MOV R0,#71H ;指向秒计时单元（71H-72H）
ACALL ADD1 ;调用加1程序（加1秒操作）
MOV A,R3 ;秒数据放入A（R3为2位十进制数组合）
CLR C ;清进位标志
CJNE A,#60H,ADDMM ;
ADDMM: JC OUTT0 ;小于60秒时中断退出
ACALL CLR0 ;大于或等于60秒时对秒计时单元清0
MOV R0,#77H ;指向分计时单元（76H-77H）
ACALL ADD1 ;分计时单元加1分钟
MOV A,R3 ;分数据放入A
CLR C ;清进位标志
CJNE A,#60H,ADDHH ;
ADDHH: JC OUTT0 ;小于60分时中断退出
ACALL CLR0 ;大于或等于60分时分计时单元清0
MOV R0,#79H ;指向小时计时单元（78H-79H）
ACALL ADD1 ;小时计时单元加1小时
MOV A,R3 ;时数据放入A
CLR C ;清进位标志
CJNE A,#24H,HOUR ;
HOUR: JC OUTT0 ;小于24小时中断退出
ACALL CLR0 ;大于或等于24小时小时计时单元清0
OUTT0: MOV 72H,76H ;中断退出时将分、时计时单元数据移
MOV 73H,77H ;入对应显示单元
MOV 74H,78H ;
MOV 75H,79H ;
POP PSW ;恢复状态字（出栈）
POP ACC ;恢复累加器
SETB ET0 ;开放T0中断
RETI ;中断返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 闪动调时 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中断服务程序，用作时间调整时调整单元闪烁指示
INTT1: PUSH ACC ;中断现场保护
PUSH PSW ;
MOV TL1,#0B0H ;装定时器T1定时初值
MOV TH1,#3CH ;
DJNZ R2,INTT1OUT ;0.3秒未到退出中断（50MS中断6次）
MOV R2,#06H ;重装0.3秒定时用初值
CPL 02H ;0.3秒定时到对闪烁标志取反
JB 02H,FLASH1 ;02H位为1时显示单元"熄灭"
MOV 72H,76H ;02H位为0时正常显示
MOV 73H,77H ;
MOV 74H,78H ;
MOV 75H,79H ;
INTT1OUT: POP PSW ;恢复现场
POP ACC ;
RETI ;中断退出
FLASH1: JB 01H,FLASH2 ;01H位为1时，转小时熄灭控制
MOV 72H,7AH ;01H位为0时，"熄灭符"数据放入分
MOV 73H,7AH ;显示单元（72H-73H），将不显示分数据
MOV 74H,78H ;
MOV 75H,79H ;
AJMP INTT1OUT ;转中断退出
FLASH2: MOV 72H,76H ;01H位为1时，"熄灭符"数据放入小时
MOV 73H,77H ;显示单元（74H-75H），小时数据将不显示
MOV 74H,7AH ;
MOV 75H,7AH ;
AJMP INTT1OUT ;转中断退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ADD1: MOV A,@R0 ;取当前计时单元数据到A
DEC R0 ;指向前一地址
SWAP A ;A中数据高四位与低四位交换
ORL A,@R0 ;前一地址中数据放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十进制调整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位变0
MOV @R0,A ;放回前一地址单元
MOV A,R3 ;取回R3中暂存数据
INC R0 ;指向当前地址单元
SWAP A ;A中数据高四位与低四位交换
ANL A,#0FH ;高四位变0
MOV @R0,A ;数据放入当削地址单元中
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清零程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;对计时单元复零用
CLR0: CLR A ;清累加器
MOV @R0,A ;清当前地址单元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址单元清0
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 时钟调整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;当调时按键按下时进入此程序
SETMM: CLR ET0 ;关定时器T0中断
CLR TR0 ;关闭定时器T0
LCALL DL1S ;调用1秒延时程序
JB P3.7,CLOSEDIS;键按下时间小于1秒，关闭显示（省电）
MOV R2,#06H ;进入调时状态，赋闪烁定时初值
SETB ET1 ;允许T1中断
SETB TR1 ;开启定时器T1
SET2: JNB P3.7,SET1 ;P3.7口为0（键未释放），等待
SETB 00H ;键释放，分调整闪烁标志置1
SET4: JB P3.7,SET3 ;等待键按下
LCALL DL05S ;有键按下，延时0.5秒
JNB P3.7,SETHH ;按下时间大于0.5秒转调小时状态
MOV R0,#77H ;按下时间小于0.5秒加1分钟操作
LCALL ADD1 ;调用加1子程序
MOV A,R3 ;取调整单元数据
CLR C ;清进位标志
CJNE A,#60H,HHH ;调整单元数据与60比较
HHH: JC SET4 ;调整单元数据小于60转SET4循环
LCALL CLR0 ;调整单元数据大于或等于60时清0
CLR C ;清进位标志
AJMP SET4 ;跳转到SET4循环
CLOSEDIS: SETB ET0 ;省电（LED不显示）状态。开T0中断
SETB TR0 ;开启T0定时器（开时钟）
CLOSE: JB P3.7,CLOSE ;无按键按下，等待。
LCALL DISPLAY ;有键按下，调显示子程序延时削抖
JB P3.7,CLOSE ;是干扰返回CLOSE等待
WAITH: JNB P3.7,WAITH ;等待键释放
LJMP START1 ;返回主程序（LED数据显示亮）
SETHH: CLR 00H ;分闪烁标志清除（进入调小时状态）
SETHH1: JNB P3.7,SET5 ;等待键释放
SETB 01H ;小时调整标志置1
SET6: JB P3.7,SET7 ;等待按键按下
LCALL DL05S ;有键按下延时0.5秒
JNB P3.7,SETOUT ;按下时间大于0.5秒退出时间调整
MOV R0,#79H ;按下时间小于0.5秒加1小时操作
LCALL ADD1 ;调加1子程序
MOV A,R3 ;
CLR C ;
CJNE A,#24H,HOUU ;计时单元数据与24比较
HOUU: JC SET6 ;小于24转SET6循环
LCALL CLR0 ;大于或等于24时清0操作
AJMP SET6 ;跳转到SET6循环
SETOUT: JNB P3.7,SETOUT1 ;调时退出程序。等待键释放
LCALL DISPLAY ;延时削抖
JNB P3.7,SETOUT ;是抖动，返回SETOUT再等待
CLR 01H ;清调小时标志
CLR 00H ;清调分标志
CLR 02H ;清闪烁标志
CLR TR1 ;关闭定时器T1
CLR ET1 ;关定时器T1中断
SETB TR0 ;开启定时器T0
SETB ET0 ;开定时器T0中断（计时开始）
LJMP START1 ;跳回主程序
SET1: LCALL DISPLAY ;键释放等待时调用显示程序（调分）
AJMP SET2 ;防止键按下时无时钟显示
SET3: LCALL DISPLAY ;等待调分按键时时钟显示用
AJMP SET4
SET5: LCALL DISPLAY ;键释放等待时调用显示程序（调小时）
AJMP SETHH1 ;防止键按下时无时钟显示
SET7: LCALL DISPLAY ;等待调小时按键时时钟显示用
AJMP SET6
SETOUT1: LCALL DISPLAY ;退出时钟调整时键释放等待
AJMP SETOUT ;防止键按下时无时钟显示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 显示程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 显示数据在70H-75H单元内，用六位LED共阳数码管显示，P1口输出段码数据，P3口作
; 扫描控制，每个LED数码管亮1MS时间再逐位循环。
DISPLAY: MOV R1,#70H ;指向显示数据首址
MOV R5,#0FEH ;扫描控制字初值
PLAY: MOV A,R5 ;扫描字放入A
MOV P3,A ;从P3口输出
MOV A,@R1 ;取显示数据到A
MOV DPTR,#TAB ;取段码表地址
MOVC A,@A+DPTR ;查显示数据对应段码
MOV P1,A ;段码放入P1口
LCALL DL1MS ;显示1MS
INC R1 ;指向下一地址
MOV A,R5 ;扫描控制字放入A
JNB ACC.5,ENDOUT ;ACC.5=0时一次显示结束
RL A ;A中数据循环左移
MOV R5,A ;放回R5内
AJMP PLAY ;跳回PLAY循环
ENDOUT: SETB P3.5 ;一次显示结束，P3口复位
MOV P1,#0FFH ;P1口复位
RET ;子程序返回
TAB: DB 0C0H,0F9H,0A4H,0B0H,099H,092H,082H,0F8H,080H,090H,0FFH
;共阳段码表 "0" "1" "2" "3" "4" "5" "6" "7" "8" "9" "不亮"
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 延时程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延时程序，LED显示程序用
DL1MS: MOV R6,#14H
DL1: MOV R7,#19H
DL2: DJNZ R7,DL2
DJNZ R6,DL1
RET
;20MS延时程序，采用调用显示子程序以改善LED的显示闪烁现象
DS20MS: ACALL DISPLAY
ACALL DISPLAY
ACALL DISPLAY
RET
;延时程序，用作按键时间的长短判断
DL1S: LCALL DL05S
LCALL DL05S
RET
DL05S: MOV R3,#20H ;8毫秒*32=0.196秒
DL05S1: LCALL DISPLAY
DJNZ R3,DL05S1
RET
;
END ;程序结束

---

石狮市17361242910： 以51单片机为核心器件,组成一个电子时钟系统. - ？
林古中宝： 调用定时器中断,发出一个频率1s的脉冲,用这个来计数.加上几个按键,按键接收到一个电平信号这个数也+1.满60清零,分钟那个数+1,分钟满60清零,小时加1.在循环中不停的和你设定的定时时间做对比,一旦相同就启动蜂鸣器提醒.

石狮市17361242910： 跪求51单片机电子钟程序 - ？
林古中宝： 51的片子,读书时的课程设计中的部份,当时觉得写的还不错,现在看起来有点夸张,有很大的发挥简化空间,很多语句都不成熟,但是还是完成了设计要求了,这是未简化的版本,里面有电路图和程序(用汇编语言写的),现放在我的空间里,自己去下吧http://www.hsz.ik8.com/baidu/mcu.rar 里面可设两个闹钟,可以设置开和关.可以调时间还有日期也能调包括年月日小时分钟秒. 想要农历功能也行,不过要加分哈哈

石狮市17361242910： 求一基于单片机的项目??? - ？
林古中宝： 基于单片机的万年历 (用DS1302 和DS18B20 ,可以显示年月日 周 时分秒 温度 ,可调) 基础的话可以从 蜂鸣器 、流水灯、数码管显示(静态和动态)、按键(独立按键和矩阵键盘)、LCD液晶显示、无线接收等一个一个小的模块学习,最后可以做一个综合的实验(万年历).

石狮市17361242910： 以单片机为核心,设计一个小型的家庭智能控制系统. - ？
林古中宝： 1、温度用18B20吧,单总线,网上资料大把大把的.也就5元左右一个 2、湿度用湿度传感器或者湿敏电阻,后者便宜一些大概3-10元能搞定 3、防盗情况 判断门的开闭可以用门磁传感器,也就是门上贴块磁铁,旁边放个干簧管,闭合的时候磁...

石狮市17361242910： 基于单片机的电子时钟 - ？
林古中宝： 去百度文库,查看完整内容> 内容来自用户:啊宝1688 绪论 单片机在多功能数字电子钟中的应用已是非常普遍,人们对电子时钟的功能及工作顺序都已非常熟悉了,但是却很少知道它的内部结构以及工作原理.由单片机作为电子时钟的核心控...

石狮市17361242910： 单片机c语言点阵 - ？
林古中宝： 1,点阵恰恰简单,120元搞.4个字的屏2,数字电压表也简单的,不要钱的,程度到电路我都有.如果要实物,很简单的啦.80元.

石狮市17361242910： 求助——电子:使用单片机做一个设计......... - ？
林古中宝： 用单片机和一个压敏电阻和LED显示屏组成,压敏电阻返回的数据经单片机处理,将网上下载的资料存在EEPROM里,将压敏电阻测得的数据和存在EEPROM的数据进行比较,再输出到LED显示屏就好了.

石狮市17361242910： 彩灯控制器c语言1.设计要求以单片机为核心,设计一个节日彩灯控制? ？
林古中宝： 这个不难,根据你的要求,P1. 2接开关,P0和P2口分别接两排16个LED灯,程序如下:#include #define uchar unsigned char #define uint unsigned intsbit key=P1^2; ...

石狮市17361242910： 请帮忙设计一个以80C51单片机为核心的光控自动窗帘电路图(带手动). - ？
林古中宝： 难道有什么高级功能?用光敏电阻和比较器(LM339)或者一个ADC组成光感模块,然后输入…… 手动就接个按钮……一个端口 电机控制用三极管,达林顿管最好了……一个端口 你选用的光敏电阻阻值不同,LM358一边的电阻要调整一下~ 还有你的H桥是否有用~ PS.留言给我吧~

石狮市17361242910： 我想用单片机做一个电子电位器 - ？
林古中宝： 你那两个放大器都行,我以前做过用的是LM324,它不能单电源供电.你可以用7812和7912做一个吗,很简单的,成本也不高.UA741这是一个老牌运放了,他可以用单电源分压,不过也不能用5V,基本上就是9到12V,